Yes, this thread is long and confusing. Here is the inno installer for my most recent map:
http://www.gpsfiledepot.com/maps/view/276/This script will work fine to create a universal version of any map if you customize it with the correct info for your map. The only thing it doesn't do is remove an older map. But as long as you're creating new maps and not updates, it should be fine. Here are a few notes
1. You must generate your own unique AppID using the Inno Setup compiler. Do NOT use the ID below. The purpose of this ID is to create an uninstaller for the map.
2. the .gmapi folder, installer script, license and any other support files all must be in the same directory. The support files are listed below - if you don't want any of them, just comment the appropiate lines out of the script.
3. If you would like the installer (.exe file) to have a custom icon, it must be an .ico file. I used the free GreenFish icon editor to create one myself.
4. Create a text file named license.txt containing your license.
5. You can create a custom image to be displayed during installation. It needs to be a .bmp file 164 pixels wide x 314 pixels high.
6. Change the value of OutputDir to something that makes sense on your own system.
7. After creating the Windows installer and compiling with Inno Setup Compiler, create a folder named for your map and put both Windows Installer.exe and your .gmapi folder into it. Now compess that folder as a .zip archive and you should be all set.
#define MyAppName "Boyds Map of the Pines LE"
#define MyAppVersion "1.0"
#define MyAppPublisher "Boyd's Maps"
[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{91A47A34-7409-455D-967E-A632501AFF80}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppPublisher={#MyAppPublisher}
; writes maps files to proper directories in XP, Vista and Win 7 so Mapsource and Basecamp can find them.
DefaultDirName={commonappdata}\GARMIN\Maps
DisableDirPage=yes
DefaultGroupName={#MyAppName}
DisableProgramGroupPage=yes
;optional custom icon for the installer
SetupIconFile=PinesMap.ico
; optional custom image you want displayed on your installer
WizardImageFile=PinesMapLE.bmp
; your license agreement that requires acceptance before installer will continue with installation.
LicenseFile=license.txt
; folder you want the installer written to.
OutputDir=C:\Users\ostroff\Desktop\mapping\ned19\pines map\work\inno
; installer name
OutputBaseFilename=Windows Installer
Compression=lzma
SolidCompression=yes
[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"
[Messages]
FinishedLabel=Setup has finished the installation of Boyd's Map of the Pines LE on your computer. You may now run Garmin Basecamp or Mapsource and choose "Boyds Map of the Pines LE" from the dropdown menu to view the map. To remove this map, use the uninstall option in the Programs and Features control panel (Windows 7 and Vista) or Add/Remove Programs (Windows XP)
WelcomeLabel2=This will install Boyd's Map of the Pines LE on your computer.%n%nIt is recommended that you close all other applications before continuing. NOTE: You must install Garmin BaseCamp or Mapsource in order to use this map. You may download BaseCamp from: http://www8.garmin.com/support/download_details.jsp?id=4435
[Files]
;copy .gmapi folder from install folder to user's Maps folder
Source: "{src}\Boyds Map of the Pines LE.gmapi\*"; DestDir: "{commonappdata}\GARMIN\Maps"; Flags: external ignoreversion recursesubdirs createallsubdirs
[Icons]
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"
;